Help script comanda cleo

[Xspression]

Salut,

Am un script cleo cu o comanda pe care trebuie sa o activez când întru în joc ca modul sa functioneze.Vreau sa-l modific și anume as vrea ca modul sa se activeze imediat după ce intru pe server fără sa îl activez eu manual.

Aici este scriptul.

CLEO .cs}
{$USE bitwise}

0000: NOP

:Noname_2
wait 50
SAMP.Available
jf @Noname_2
0B34: samp register_client_command "helmet" to_label @Noname_227
chatmsg "{FF8000}AutoHelmet has loaded." color -1
chatmsg "{FF8000}Use command {0080ff}/helmet{FF8000} to activate." color -1

:Noname_130
wait 0
if
31@ == 1
jf @Noname_220
if
Actor.Driving($PLAYER_ACTOR)
jf @Noname_213
if
14@ == 1
jf @Noname_206
wait 500
say "/ph"
14@ = 0

:Noname_206
jump @Noname_220

:Noname_213
14@ = 1

:Noname_220
jump @Noname_130

:Noname_227
0B12: 31@ = 31@ XOR 1
if
31@ == 1
jf @Noname_311
chatmsg "{FF0000}Auto helmet is now enabled!" color -1
14@ = 1
jump @Noname_354

:Noname_311
chatmsg "{FF0000}Auto helmet is now disabled!" color -1

:Noname_354
SAMP.CmdRet

Ma puteți ajuta va rog?

[RW YuukiKING]

Nu aici trebuia sa pui topicul, cel mai probabil aici in sectiunea asta: https://forum.b-zone.ro/forum/382-help-and-discussions/

 

Te rog sa il postezi acolo aici deobicei postezi daca ai probleme legate de joc nu cu anumite moduri/cmd uri.

[Tupi]

{CLEO .cs}

0000: NOP
repeat
wait 50
until 0AFA:

0B34: samp register_client_command "helmet" to_label @Noname_227
chatmsg "{FF8000}AutoHelmet has loaded." color -1
chatmsg "{FF8000}Use command {0080ff}/helmet{FF8000} to deactivate." color -1
14@ = 1
31@ = 1

:Noname_130
wait 0
if 31@ == 1
then
    if Actor.Driving($PLAYER_ACTOR)
    then
        if 14@ == 1
        then
            wait 500
            say "/ph"
            14@ = 0
        end
    else 14@ = 1
    end
end
jump @Noname_130

:Noname_227
0B12: 31@ = 31@ XOR 1
if 31@ == 1
then 
    chatmsg "{FF0000}Auto helmet is now enabled!" color -1
    14@ = 1
else
    chatmsg "{FF0000}Auto helmet is now disabled!" color -1
    14@ = 0
end
SAMP.CmdRet

 

Ti-am corectat putin scriptul că nu înțelegeam nimic din el, însă funcționabilitatea ar trebui să fie aceiași.

[Xspression]

 

Am rezolvat,multumesc pentru ajutor.Se poate da close la topic.

Edited March 20, 2023 by Xspression

[Tupi]

Dacă mai ai nevoie de ajutor poți deschide un topic nou în aceasta secțiune.